#include "colors.inc"
#include "textures.inc"

//global_settings {
//  radiosity {
//    pretrace_start 0.08
//    pretrace_end   0.04
//    count 35
//
//    nearest_count 5
//    error_bound 1.8
//    recursion_limit 3
//
//    low_error_factor 0.5
//    gray_threshold 0.0
//    minimum_reuse 0.015
//    brightness 1
//
//    adc_bailout 0.01/2
//  }
//}

camera {
  location <0, 1.15, -0.5>
  look_at  <2, 1, 0.2>
  aperture 0.05
  blur_samples 100
  focal_point  <1, 1, 0.2>
  variance 1/1000
}

light_source { <1, 1, -2> color White}
light_source { <4, 1, -2> color White}
light_source { <-2, 4, 1> color White}
light_source { <1, 1, 10> color White}
light_source { <4, 1, 10> color White}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.000 0.002 color rgb <1.0, 0.2, 0.0>
                   color rgb <1.0, 0.2, 0.0>]
      [0.002 0.200 color rgb <0.8, 0.1, 0.0>
                   color rgb <0.2, 0.2, 0.3>]
    }
    scale 2
    translate -1
  }

  rotate -135*x
  rotate <-125, 60, 0>
}

fog {
    distance 5
    color rgbf <0.2, 0.2, 0.7, 0.2>
}

#macro burk(xpos, ypos, zpos)

  box {
    <xpos+0.029, ypos, zpos+0.003>,
    <xpos+0.029+0.425, ypos+0.088, zpos+0.003+0.654>
    texture {
       pigment { color White }
       finish {ambient 0}
    }
  }

  box {
    <xpos+0.029, ypos, zpos>,
    <xpos+0.029+0.425, ypos+0.088, zpos+0.003>
    texture {
       pigment {
         image_map { png "front.png" }
         scale <0.425, 0.088, 1>
         translate <xpos+0.029, ypos, zpos>
       }
       finish {ambient 0}
    }
  }


  box {
    <xpos, ypos, zpos>,
    <xpos+0.029, ypos+0.088, zpos+0.003>
    texture { Aluminum }
  }

  sphere_sweep {
    linear_spline
    4,
    <xpos+0.015, ypos+0.015, 0>, 0.005
    <xpos+0.015, ypos+0.022, -0.010>, 0.005
    <xpos+0.015, ypos+0.066, -0.010>, 0.005
    <xpos+0.015, ypos+0.073, 0>, 0.005
    texture { Aluminum }
  }

  box {
    <xpos+0.029+0.425, ypos, zpos>,
    <xpos+0.029+0.425+0.029, ypos+0.088, zpos+0.003>
    texture { Aluminum }
  }

  sphere_sweep {
    linear_spline
    4,
    <xpos+0.015+0.029+0.425, ypos+0.015, 0>, 0.005
    <xpos+0.015+0.029+0.425, ypos+0.022, -0.010>, 0.005
    <xpos+0.015+0.029+0.425, ypos+0.066, -0.010>, 0.005
    <xpos+0.015+0.029+0.425, ypos+0.073, 0>, 0.005
    texture { Aluminum }
  }

  box {
    <xpos+0.42, ypos+0.06, 0>,
    <xpos+0.424, ypos+0.062, -0.001>
    material {
      texture {
        pigment { color rgb <0, 1, 0> }
        finish {
          specular 1
          roughness 0.001
          ambient 4
          diffuse 0
          reflection 0.1
	}
      }
      interior {ior 1.5}
    }
  }

#end

#declare yn = 0;

#while(yn < 20)
  #declare xn = 0;
  #while(xn < 11)
    burk(xn*0.5, yn*0.1, 0)
    #declare xn = xn+1;
  #end
  #declare yn = yn+1;
#end

plane {
  y, 0
  pigment {
    color White
  }
}